Delphi控件开发浅入深出(三)
三、开关控件TlincoSwitch
用过Delphi1(好古老的东东呀!)的人相信都记得这个开关控件 ,不知道当初Borland为什么把这么一个在开发普通应用程序中应用不到的工控控件放到Delphi中,而且在Delphi2及其以后的版本中再也没有见过它的身影。让我们怀着怀旧的心情把这位“开国元老”请出来吧!
1、建立位图资源文件:
用Image Editor建立一个Res文件,并在文件中分别建立下面两个位图,并分别命名为SWITCHON、SWITCHOFF。保存此Res到控件单元所在目录下。
2、写控件代码。
unit LincoSwitch;
interface
uses
SysUtils, Classes, Controls, Graphics, Windows;
type
TLincoSwitch = class(TCustomControl)
private
FIsOn: Boolean;
FPicOn: Graphics.TBitmap;
FPicOff: Graphics.TBitmap;
procedure FSetIsOn(AValue: Boolean);
protected
procedure Click;override;
procedure Paint;override;
public
constructor Create(AOwner: TComponent);override;
destructor Destroy;override;
published
property IsOn: Boolean read FIsOn write FSetIsOn;
property OnClick;
property OnKeyDown;
property OnKeyPress;
property OnKeyUp;
property OnCanResize;
property OnDblClick;
property OnMouseDown;
property OnMouseMove;
property OnMouseUp;
property OnMouseWheel;
property OnResize;
end;
procedure Register;
implementation
{$R *.res}
procedure LoadBitmapFromRes(ABitmapId: string; ABitmap: Graphics.TBitmap);
begin
ABitmap.LoadFromResourceName(hInstance, ABitmapId);//从资源文件中读取位图
end;
constructor TLincoSwitch.Create(AOwner: TComponent);
begin
inherited Create(AOwner);
FPicOn := Graphics.TBitmap.Create;
FPicOff := Graphics.TBitmap.Create;
LoadBitmapFromRes('SWITCHON', FPicOn);
LoadBitmapFromRes('SWITCHOFF', FPicOff);
Invalidate;
end;
destructor TLincoSwitch.Destroy;
begin
FPicOn.Free;
FPicOff.Free;
inherited;
end;
procedure TLincoSwitch.Click;
begin
IsOn := not IsOn;//改变按钮的状态
Invalidate;
inherited;
end;
procedure TLincoSwitch.Paint;
begin
//画开关图案
if IsOn then
StretchBlt(Canvas.Handle, 0, 0, self.Width, self.Height, FPicOn.Canvas.Handle,
0, 0, FPicOn.Width, FPicOn.Height,SRCCOPY)
else
StretchBlt(Canvas.Handle, 0, 0, self.Width, self.Height, FPicOff.Canvas.Handle,
0, 0, FPicOff.Width, FPicOff.Height,SRCCOPY);
end;
procedure TLincoSwitch.FSetIsOn(AValue: Boolean);
begin
FIson := AValue;
Invalidate;
end;
procedure Register;
begin
RegisterComponents('Linco', [TLincoSwitch]);
end;
end.
3、代码分析
(1)、因为我们要在控件表面上将按钮的图案画出来,所以我们选择TcustomControl做为父类控件,因为它有个Canvas属性,我们可以利用Canvas在控件表面作图。不选用Tcontrol的原因是因为它有很多我们不需要的属性。
(2)、ABitmap.LoadFromResourceName(hInstance, ABitmapId);是从资源文件中读取Id为AbitmapId的位图,关于资源文件的使用请参考其他相关资料。注意代码中的“{$R *.res}”,它的作用是将资源文件编译到程序文件中,如果没有这个预编译条件,程序将会出现错误。
(3)、StretchBlt是将位图画到画板上,使用方法请参考MSDN。
(4)、我们为控件增加了IsOn属性。这个布尔属性用来表示开关的状态(开/关)。
从property IsOn: Boolean read FIsOn write FSetIsOn;我们可以看出这个属性是个可读可写的属性。当读这个属性时会将FisOn的值返回给调用者,而写属性时则会调用FsetIsOn方法,并将赋给属性的值做为参数传递给FsetIsOn。在FsetIsOn方法中,有如下实现代码:
FIson := AValue;
Invalidate;
首先将Fison设置为参数传递来的值,然后调用 Invalidate;要求重画控件,以告诉用户控件的状态已经改变,这一点是使用写字段无法做到的。
(5)
FPicOn: Graphics.TBitmap;
FPicOff: Graphics.TBitmap;
是声明两个.Tbitmap类型变量以保存控件的开关两种状态的图案。
(6)
procedure Click;override;
procedure Paint;override;
分别是覆盖父类中相应的调度方法。当控件被鼠标单击时,Click方法会被调用,我们将在Click中改变控件的开关状态;Paint方法则在用户调用 Invalidate方法或控件发生重画时调用,我们一般在这个方法绘制控件的图案。
(7)、TcustomControl中又很多事件处理句柄。比如OnClick、OnKeyDown等,但是它把他们声明成了Protected保护级别,所以我们在Object Inspector中看不到他们,如果我们要他们可以在Object Inspector中被用户编辑的话,只要在Published中重新声明他们即可,不用写他们的读写方法,只要使用:Property 属性名;
这样的方法就可以。比如这个例子中的:Property Onclick;
思考题:
1、 做一个有特效的按钮控件,当鼠标按下时按钮是一个红色边框的空心圆,当鼠标松开时按钮是一个淡绿色边框的空心圆。
2、 对于父类控件中为protected的属性,如果想将它在子类控件中公布,应该怎么做?请思考Delphi为什么要将一些属性设为protected级别?
相关文章
- WinForm开发中针对TreeView控件改变当前选择节点的字体与颜色
- 微信开发 问题汇总
- IOS学习资源收集--开发UI控件相关
- iOS开发UI篇—UITableview控件使用小结
- 预约下载 | 《Serverless 开发速查手册》全新上线
- 【ANDROID游戏开发二十三】自定义LISTVIEW【通用】适配器并实现监听控件!
- Cocos开发中性能优化工具介绍之Xcode中Instruments工具使用
- Qt音视频开发11-通用监控布局控件(开源)
- 阿里云在线web IDE:云效云端开发 DevStudio(ide.aliyun.com)
- C++ OCX控件开发后出现的注册问题
- C#自定义工业控件开发
- ArcGIS Engine开发之旅03--ArcGIS Engine中的控件
- SAP UI5 应用开发教程之六十四 - 基于 OData V4 的 SAP UI5 表格控件如何实现 filter(过滤) 和 sort(排序)功能试读版
- SAP UI5 应用开发教程之六十二 - 基于 OData V4 的 SAP UI5 表格控件使用方法介绍试读版
- SAP UI5 应用开发教程之六十 - SAP UI5 地图控件的一些高级用法试读版
- SAP UI5 应用开发教程之五十六 - SAP UI5 树控件(tree)的开发试读版
- SAP Gateway 在开发系统和生产系统上的缓存控制
- 在 Kyma 云原生平台上开发并部署 Node.js 应用
- SAP UI5 应用开发教程之九十五 - SAP UI5 下拉菜单(Select) 控件的使用方式试读版
- SAP UI5 应用开发教程之九十三 - 基于 JSONModel 数据模型的列表控件显示数据的深入讨论试读版
- SAP UI5 应用开发教程之七十 - 如何使用按钮控件触发页面路由跳转试读版
- SAP UI5 应用开发教程之六十四 - 基于 OData V4 的 SAP UI5 表格控件如何实现 filter(过滤) 和 sort(排序)功能试读版
- SAP UI5 应用开发教程之三十二 - 如何创建一个自定义 SAP UI5 控件试读版
- 深入浅出 - Android系统移植与平台开发(十三)- Android的对象管理
- java使用maven项目(二)分模块开发
- android应用开发--------------看RadioGroup源代码,写相似单选选项卡的集成控件(如底部导航,tab等等)
- C#里WinForm开发中如何实现控件随窗体大小的改变而自动适应其改变(转)
- 对于新开发完成的软件来说,做测试需求管理时有哪些难点系带我们解决?
- 用VS ATL工程开发播放Gif图片控件的步骤