VBA实战技巧：正确登录后才能使用Excel工作簿

Private Sub btnCancel_Click()
   ThisWorkbook.Close SaveChanges:=False
End Sub
Private Sub btnOK_Click()
    Dim iFoundPass As Integer
    On Error Resume Next
    With Sheets("用户中心").Range("UserName")
       iFoundPass = .Find(What:=txtUserName, After:=.Cells(1, 1),LookIn:=xlValues, LookAt _
         :=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
         False).Row
    End With
    On Error GoTo 0
    If iFoundPass = 0 Then
       SomethingWrong
        Exit Sub
    End If
    If Sheets("用户中心").Cells(iFoundPass,2) <> txtPassword Then
       SomethingWrong
        Exit Sub
    ElseIf Sheets("用户中心").Cells(iFoundPass,3) < Date Then
       Expired
        Exit Sub
    End If
   Sheets("用户中心").Range("LoggedAs")= txtUserName
    Unload Me
End Sub
Private Sub txtPassword_Change()
   btnOK.Enabled = (txtUserName.TextLength > 4 And _
                      txtPassword.TextLength> 4)
End Sub
Private Sub UserForm_Initialize()
   Me.btnOK.BackStyle = fmBackStyleTransparent
End Sub
Private Sub UserForm_QueryClose(Cancel As Integer,CloseMode As Integer)
    If CloseMode = 0 Then Cancel = True
End Sub
Private Sub txtUserName_Change()
    btnOK.Enabled= (txtUserName.TextLength > 4 And _
                      txtPassword.TextLength> 4)
End Sub
Private Sub SomethingWrong()
   MsgBox"用户名或密码不正确.",vbCritical + vbInformation, "错误"
End Sub
Private Sub Expired()
   MsgBox"你的许可已过期.请联系申请延期或完全许可",vbCritical + vbInformation, "完美Excel"
End Sub

Private Sub Workbook_Open()
 Application.EnableCancelKey = xlDisabled
 Sheets("数据").Activate
 Sheets("用户中心").Visible= xlVeryHidden
  login.Show
End Sub