VBA: Excel文件批量转化为pdf (2)

Option Explicit

Sub ConvertFiles()

    '批量转化Excel文件为pdf
    Dim filefolder As String
    
    Dim fd As FileDialog, t As String, str As String, name As String
    
    Application.ScreenUpdating = False
    
    '获取默认路径
    ChDrive ThisWorkbook.Worksheets("Sheet1").Range("B2").Value
    ChDir ThisWorkbook.Worksheets("Sheet1").Range("B3").Value
    
    '1 选择需要转化的文件夹路径
    Set fd = Application.FileDialog(msoFileDialogFolderPicker)
    
    With fd
    
        If .Show = -1 Then
        
            t = .SelectedItems(1)
            
        Else
        
            MsgBox "未选取文件夹！"
            
            Exit Sub
            
        End If
    
    End With
    
    '2 创建储存pdf文件的空文件夹
    filefolder = ThisWorkbook.Worksheets("Sheet1").Range("B3").Value & "\pdf文件"
    
    If Not isDirectory(filefolder) Then
    
        VBA.MkDir (filefolder)
        
    Else
    
        MsgBox "默认路径的pdf文件夹已存在，请确认！"
        
        Exit Sub
    
    End If
    
    '3 批量转化excel文件
    str = Dir(t & "\*.xls*")   ' 查找excel文件
    Do While Len(str) > 0
    
        Workbooks.Open (t & "\" & str)
        
        name = CreateObject("Scripting.FileSystemobject").getextensionname(str)  '获取文件的扩展名
        
        ActiveWorkbook.Worksheets(1).PrintOut copies:=1, preview:=False, ActivePrinter:="Microsoft Print to PDF" _
            , PrintToFile:=True, PrToFileName:=filefolder & "\" & Replace(str, name, "pdf"), IgnorePrintAreas:=False
        
        Workbooks(str).Close False
        
        str = Dir()
        
    Loop
    
    MsgBox "Done!"
    
    Application.ScreenUpdating = True
    
    Exit Sub

End Sub

Function isDirectory(pathName As String) As Boolean

    '用于判断文件夹是否存在
    
    Dim fso As Object
    
    Set fso = CreateObject("Scripting.FileSystemObject")
    
    isDirectory = fso.FolderExists(pathName)

End Function